Go Back   Desktop & Server Management (DSM) Forum > GERMAN > DSM 7 > DSM 7 Imaging
Register FAQ Members List Calendar Search Today's Posts Mark Forums Read

Closed Thread
 
Thread Tools Search this Thread Display Modes
  #1  
Old September 2nd, 2013, 09:32
BaSe BaSe is offline
Benutzer
 
Join Date: 02-17-11
Posts: 70
Ausrufezeichen [SOLVED] 5 Partionen

Hallo,

ich muß ein Dualboot System ausrollen. Das System besteht aus 5 Partitionen:

100 MB Bootpartition (NTFS)
100 GB Windows Partition 7 (NTFS)
120 GB Datenpartition (NTFS)
30 GB Windows XP Partition (NTFS)
300 MB Lizenzpartition (NTFS)

Dadurch das nur 4 primäre Partitionen möglich sind möchte ich die 300 MB Lizenzpartition als erweiterte Partition anlegen, aber ich weiß nicht wie das von statten geht. Im OS Set ist noch ein Option "Extended Partition , yes | no", aber für was ist die?

Mein Partitioning and Formatting for multiple partitions Script sieht zur Zeit so aus:

Code:
@echo off
echo Partitioning and formatting multiple Partitions
echo Partitioning and formatting multiple Partitions > _out.txt

IF NOT "%%OS%%" == "Windows_NT" GOTO wrongOS_error
IF NOT EXIST X:\ENTEO\osdclnt.ini GOTO wrongOS_error

regedit /s PE20PartAlign.reg

set disknumber=0
set formatParams=/Y
if "%InstallationParameters.QuickFormat%" == "1" set formatParams=%%formatParams%% /Q
if /I not "%InstallationParameters.ClusterSize%"=="default" set formatParams=%%formatParams%% /A:%InstallationParameters.ClusterSize%

set scale=1
if "%InstallationParameters.UnitSize%" == "MB" goto scale_end
set scale=1024
if "%InstallationParameters.UnitSize%" == "GB" goto scale_end
set scale=0
for /F "tokens=1,2 delims==" %%%%a in ('wmic diskdrive where "index=%%disknumber%%" get size /format:list') do if "%%%%a"=="Size" set scale=%%%%b
rem clean unicode
set scale=%%scale%%
echo Disk size is %%scale%% Bytes >> _out.txt
rem divide by 100000 (100 for percentages and 1000 to get it in 31 bit)
set scale=%%scale:~0,-5%%
rem convert to KB
set /A scale=scale/1024
rem convert to MB (correct the 1000 to 1024)
set /A scale=scale*1000
set /A scale=scale/1024
if "%%scale%%"=="" goto scale_error
if "%%scale%%"=="0" goto scale_error
:scale_end
echo Unit size is %%scale%% MB >> _out.txt

set align_param=
set align=0
set /A align=%InstallationParameters.Alignment%
if not "%%align%%"=="0" set align_param=align=%%align%%

set diskfull=0
set activate_partition=0
if "%%disknumber%%" == "0" set activate_partition=1

echo Cleaning Disk %%disknumber%%
echo Cleaning Disk %%disknumber%% >> _out.txt
echo select disk %%disknumber%% > clean_%%disknumber%%.txt
echo clean >> clean_%%disknumber%%.txt
echo exit >> clean_%%disknumber%%.txt
echo --- Content of clean_%%disknumber%%.txt >> _out.txt
type clean_%%disknumber%%.txt >> _out.txt
echo --- >> _out.txt
diskpart /s clean_%%disknumber%%.txt >> _out.txt
if errorlevel 1 goto cleandisk_error

:createvolume_1
set volumeletter=h
set volumefs=%InstallationParameters.P1FileSystem%
set /A volumesize=scale*%InstallationParameters.P1Size%
set returnlabel=createvolume_2
goto createvolume

:createvolume_2
set volumeletter=c
set volumefs=%InstallationParameters.P2FileSystem%
set /A volumesize=scale*%InstallationParameters.P2Size%
set returnlabel=createvolume_3
goto createvolume

:createvolume_3
set volumeletter=d
set volumefs=%InstallationParameters.P3FileSystem%
set /A volumesize=scale*%InstallationParameters.P3Size%
set returnlabel=createvolume_4
goto createvolume

:createvolume_4
set volumeletter=e
set volumefs=%InstallationParameters.P4FileSystem%
set /A volumesize=scale*%InstallationParameters.P4Size%
set returnlabel=createvolume_5
goto createvolume

:createvolume_5
set volumeletter=f
set volumefs=%InstallationParameters.P5FileSystem%
set /A volumesize=scale*%InstallationParameters.P5Size%
set returnlabel=end
goto createvolume

:createvolume
echo --- Creating %%volumefs%% Volume %%volumeletter%% with size %%volumesize%%
echo --- Creating %%volumefs%% Volume %%volumeletter%% with size %%volumesize%% >> _out.txt
if "%%volumefs%%" == "NONE" goto %%returnlabel%%
echo removing Mountpoint %%volumeletter%%:
echo removing Mountpoint %%volumeletter%%: >> _out.txt
echo select volume %%volumeletter%% > remove_%%volumeletter%%.txt
echo remove >> remove_%%volumeletter%%.txt
echo exit >> remove_%%volumeletter%%.txt
echo --- Content of remove_%%volumeletter%%.txt >> _out.txt
type remove_%%volumeletter%%.txt >> _out.txt
echo --- >> _out.txt
diskpart /s remove_%%volumeletter%%.txt >> _out.txt
if not errorlevel 1 goto createvolume_part

echo volume did not exist... sleeping 2 seconds
rem ping is used as a replacement for sleep
ping 127.0.0.1 -n 3 -w 1000 > nul

:createvolume_part
echo creating new %%volumeletter%% Partition
echo creating new %%volumeletter%% Partition >> _out.txt
set local_sizeparam=
if not "%%volumesize%%" == "0" set local_sizeparam=size=%%volumesize%%
echo automount disable > create_%%volumeletter%%.txt
echo select disk %%disknumber%% >> create_%%volumeletter%%.txt
echo create partition primary %%local_sizeparam%% %%align_param%% >> create_%%volumeletter%%.txt
if "%%activate_partition%%" == "1" echo active >> create_%%volumeletter%%.txt
set activate_partition=0
echo assign letter %%volumeletter%% >> create_%%volumeletter%%.txt
echo exit >> create_%%volumeletter%%.txt
echo --- Content of create_%%volumeletter%%.txt >> _out.txt
type create_%%volumeletter%%.txt >> _out.txt
echo --- >> _out.txt
diskpart /s create_%%volumeletter%%.txt >> _out.txt
if errorlevel 1 goto createvolume_parterror
if "%%volumesize%%" == "0" set diskfull=1

echo formatting %%volumeletter%% Partition
echo formatting %%volumeletter%% Partition >> _out.txt
format %%volumeletter%%: %%formatParams%% /FS:%%volumefs%% >> _out.txt
if errorlevel 1 goto createvolume_formaterror

goto %%returnlabel%%

:scale_error
set errortext=Unable to determine disk size
goto error

:createvolume_diskfull
set errortext=Creating Partition %%volumeletter%% failed - disk is full
goto error

:createvolume_parterror
if "%%diskfull%%" == "1" goto createvolume_diskfull
set errortext=Creating Partition %%volumeletter%% failed
goto error

:createvolume_formaterror
set errortext=Formatting Partition %%volumeletter%% failed
goto error

:cleandisk_error
set errortext=Cleaning Disk %%disknumber%% failed
goto error

:wrongOS_error
set errortext=This Script works only in Windows PE
goto error

:error
echo %%errortext%%
echo %%errortext%% >> _out.txt
echo %%errortext%% > _Error.txt
exit /B 1

:end
echo Execution finished
exit /B 0
Dort schlägt das Partitionieren aber fehl da er dann die fünfte Partition als Primäre anlegen möchte.

Wie kann ich eine erweitere Partition anlegen, bin da gerade etwas ratlos.
  #2  
Old September 2nd, 2013, 10:17
derniwi derniwi is offline
Erfahrener Benutzer
 
Join Date: 02-15-12
Posts: 1,680
Default

Hallo,

Extend Partition wird dazu verwendet, den restlichen freien Sepicher für die letzte Partition zu verwenden. Das hilft dir das leider nicht.

Das Problem liegt hier:
Code:
echo create partition primary %%local_sizeparam%% %%align_param%% >> create_%%volumeletter%%.txt
Du musst im Prinzip schon bei der dritten Partition eine erweiterte Partition erstellen und dort dann zwei logische Laufwerke anlegen.
Und da würde ich dir raten, die Partitionen eher so zu planen:
1. Primäre: 100 MB Bootpartition (NTFS)
2. Primäre: 30 GB Windows XP Partition (NTFS)
3. Primäre: 100 GB Windows Partition 7 (NTFS)
4. Primäre: Die erweiterte Partition für die logischen Laufwerke
5. logisches Laufwerk: 120 GB Datenpartition (NTFS)
6. logisches Laufwerk: 300 MB Lizenzpartition (NTFS)

Gruß
Nils

Last edited by derniwi : September 2nd, 2013 at 10:22.
  #3  
Old September 4th, 2013, 09:42
BaSe BaSe is offline
Benutzer
 
Join Date: 02-17-11
Posts: 70
Default

Das ist mir klar. Ich weiß nur nicht wie ich das Script so ändern kann das er mir
die erweiterte Partition erstellt. Ich könnte die

1. Primäre: 100 MB Bootpartition (NTFS)
2. Primäre: 30 GB Windows XP Partition (NTFS)
3. Primäre: 100 GB Windows Partition 7 (NTFS)

über die Installationparameter erstellen und am Schluss des Scriptes
den Diskpart Teil manuell erstellen. Leider bin ich nicht so der Überscripter
so das ich das Script schwer verstehe.
  #4  
Old September 4th, 2013, 09:54
Mel Mel is offline
Erfahrener Benutzer
 
Join Date: 09-15-09
Posts: 1,919
Default

primäre partitionenn werden bei diskpart mit
create partition primary
erzeugt

extended partitions mit
create partition extended

und die logischen partitionen in der extended mit
create partition logical

d.h. du könntest bei den create volumes einen neuen parameter einführen, der angibt, was für eine partition es sein soll und dann die zeile in der das
create partition primary ins script geschrieben wird entsprechend anpassen
z.B.
create partition %partitiontype%
wenn der partitionstyp extended ist, dann sollte das zuweisen des laufwerksbuchstabens natürlich unterbleiben

sollen beide windows installationen gemanaged werden ? dann wird das der eigentliche spaß, denn da mußt du dann verhindern, daß die das gleiche computerobjekt benutzen...
  #5  
Old September 4th, 2013, 10:48
derniwi derniwi is offline
Erfahrener Benutzer
 
Join Date: 02-15-12
Posts: 1,680
Default

Hallo,

und dann muss man auch noch dafür sorgen, dass sowohl XP wie auch Win 7 die richtige Partition verwenden, die anderen evtl. ausgeblendet sind (damit die Systeme nicht kreuz und quer schreiben). Nicht jedes Installationsprogramm wertet die Programmpfadvariablen aus.

Billiger wäre es sicherlich, ein zweites Notebook zu kaufen... ;-)

Gruß
Nils

Last edited by derniwi : September 4th, 2013 at 11:42.
  #6  
Old September 4th, 2013, 10:56
Mel Mel is offline
Erfahrener Benutzer
 
Join Date: 09-15-09
Posts: 1,919
Default

...oder das zweite system in einer virtuellen maschine laufen zu lassen
  #7  
Old September 4th, 2013, 11:07
BaSe BaSe is offline
Benutzer
 
Join Date: 02-17-11
Posts: 70
Default

Ich hab in dem Configuration Package einen Teil, in dem der BOOT-US Bootmanager installiert wird in den Optionen zu ausblenden der Partitionen gesetzt sind. Eine VM funktioniert leider nicht da es sich um Siemens Programmiergeräte handelt die direkten Zugriff auf die Hardware brauchen.
Ist eine Vorgabe der Fachabteilung.
Closed Thread


Thread Tools Search this Thread
Search this Thread:

Advanced Search
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

vB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Forum Jump

   

All times are GMT +1. The time now is 04:14.

Powered by vBulletin Version 3.6.7
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.